Very Computer

Anyone have any ideas?

I have SP-3 installed on both machines.  It seems the only difference is
Windows 95 vs. 98; and whether or not Office/Access is installed.

Thanks in advance for the help!!

Quote:>images which were saved from the other machine are garbled.

>Anyone have any ideas?

Dave Keever

In contrast, the problem I am having is that images saved on the other
machine are completely garbled so that you can't even tell what the image is
supposed to be.  It's just a smattering of horizontal bars of color.

Any other ideas out there?

When a machine running Windows 98 writes blob data (i.e. image data)
to the database (using AppendChunk) Windows 95 and Windows NT 4.0
machines can not read that data (using GetChunk) without it being
"garbled". But 98 can read it fine.

When a machine running Windows 95 or NT 4.0 writes blob data (i.e.
image data) to the database (using AppendChunk) Windows 98 machines
can not read that data (using GetChunk) without it being "garbled".
But 95 and 4.0 can read it fine.

This is a problem only with ADO 2.0 and 2.1.  ADO 1.5 Works fine
across all systems.

This problems occurrs with SQL Server 6.5, SQL Server 7.0, and Access
97.

So this doesn't help more, but it's all  I have right now.

Jeremey Zela

On Mon, 4 Jan 1999 17:13:29 -0500, "David J. Surls"

I don't know about one machine versus another, I gave up on append chunk
rather quickly when my initial tests didn't look too good.

Simon C

I've had a similar problem with DAO 3.51.
I was using a temporary file for storing images retrived with getchunk from
the SQL Server or MS Access before displaying it.
After few hours of testing I've noticed that the "errorous" behavior was
coused by type of buffer used to receive data. After declaring it as an
array of bytes instead of array of strings "error" dissapeared. This was
coused by Unicode conversion of the string buffer written to file.

Now the procedures looks like this:

Public Function CopyFieldToFile(fd As Field) As String

Dim tmpFileName As String
Dim FileNum As Integer
Dim Buffer() As Byte

Dim BytesNeeded As Long
Dim Buffers As Long
Dim Remainder As Long
Dim Offset As Long
Dim r As Integer
Dim i As Long
Static Count As Long

    BytesNeeded = fd.FieldSize
    If BytesNeeded > 0 Then
       ' Calculate the number of buffers needed to copy
        Buffers = BytesNeeded \ ChunkSize
        Remainder = BytesNeeded Mod ChunkSize

        ' Get a unique, temporary filename:
        Count = Count + 1
        tmpFileName = App.path & "\tmp" & Count & ".tif"
        If Dir(tmpFileName) <> "" Then
            Kill tmpFileName
        End If

        ' Copy the bitmap to the temporary file chunk by chunk:
        FileNum = FreeFile
        Open tmpFileName For Binary As #FileNum

        For i = 0 To Buffers - 1
           ReDim Buffer(ChunkSize)
           Buffer = fd.GetChunk(Offset, ChunkSize)
           Put #FileNum, , Buffer()

           Offset = Offset + ChunkSize
        Next

        ' Copy the remaining chunk of the bitmap to the file:
        ReDim Buffer(Remainder)
        Buffer = fd.GetChunk(Offset, Remainder)
        Put #FileNum, , Buffer()
        Close #FileNum

    End If

    CopyFieldToFile = Trim(tmpFileName)

End Function

Private Sub CopyFileToField(FileName As String, fd As Field)

Dim ChunkSize As Long
Dim FileNum As Integer
Dim Buffer()  As Byte
Dim BytesNeeded As Long
Dim Buffers As Long
Dim Remainder As Long

Dim i As Long

    If Len(FileName) = 0 Then
        Exit Sub
    End If

    If Dir(FileName) = "" Then
        Err.Raise vbObjectError, , "Nie odnaleziono pliku: """ & FileName &
""""
    End If

    ChunkSize = 65536

    FileNum = FreeFile

    Open FileName For Binary As #FileNum

    BytesNeeded = LOF(FileNum)
    Buffers = BytesNeeded \ ChunkSize
    Remainder = BytesNeeded Mod ChunkSize

    For i = 0 To Buffers - 1
        ReDim Buffer(ChunkSize)
        Get #FileNum, , Buffer
        fd.AppendChunk Buffer
    Next

    ReDim Buffer(Remainder)
    Get #FileNum, , Buffer
    fd.AppendChunk Buffer

    Close #FileNum

End Sub

Happy programing

Two follow-up questions:
1)  Is there a performance problem or advantage to using byte arrays rather
than strings?

2)  Is there a way to "convert" fields in databases which were written using
strings?  In particular, I need to be able to read a field on a Windows
98/NT machine which was written (to a temp file) using strings on a Windows
95 machine, then write it back to the field using the byte array method you
described.  Do you know how?

Thanks for the help!!