Another 3d glasses demo! (yipee!)

Another 3d glasses demo! (yipee!)

Post by moon!cyberden!phb.. » Tue, 03 Mar 1992 07:34:04



here's a "screen-burst" demo using the 3d glass colors and "bio-feedback"
pause routine: (you'll recognize the screen or screen draw routine used)

10 GR.23:TRAP 30
15 FOR A=0 TO 159 STEP 10:T=NOT T:COLOR T+1:F.B=0 TO 9:Z=A+B:PLOT Z,0
17 DR.159-Z,79:PL.0,Z/2:DR.159,79-Z/2
20 N.B:N.A
30 POKE 708,64:POKE 709,130:GOS.100
35 POKE 709,64:POKE 708,130:GOS.100:GOTO 30
100 B=228
101 B=B-1:IF PADDLE(1)>B THEN RETURN
102 GOTO 101

Note that this one uses a slightly different pause routine (which I
forgot to replace in the last demo, so you can just replace line 100 with
this ones 100-102) that responses much more quickly to paddle
adjustments.  Here's another rundown:
line 10-graphics mode and trap (one line goes off the screen at the very
end of the draw routine)
lines 15-17-draw the starburst, using alternating (red/blue) colors
(again, adjust blue to green if you have the red/green 3d glasses rather
than the red/blue.  I'm not sure why there's a difference, but I'm pretty
sure there is...)
line 20-loop!
lines 30-35-again, switch the colors registers and pause
lines 100-102-set pause variable to maximum length (228-paddle's highest
valuse), subtract 1, if the paddle has been turned beyond it, get outta
there (a for/next wouldn't do this)..otherwise check again (goto 101)

That's it!  Again, enjoy these two demos.  The circle one is a lot
better, but I decided to post this one because I'm one person, and it
seems that certain 3d glass effects look differently to different people.

Hmm.. I just saw the Fuji on my disk box.. maybe I'll load up Fuji spin
and try it out on my glasses!  Wee!  What fun!  Maybe I'll see what
effect clear/blue glasses have on 3d stuff (get those in Rice Crispy's..
I got my red/blue in the Simpson's annual 3d issue (why we get the
Simpson's magazine, God only knows!) )
        Welllllllll....         adios...        happy self-hypnotizing!!

_______________________________________
| PhBill:  Bill Kendrick      Atari   |

| 20 so miles North of         8-bits |
| San Francisco, in beautiful   ROCK! |
|_______Marin!________________________|

 
 
 

1. 3d glass demo.

For those of you with a pair of 3d glasses, try this demo:

10 GR.23:POKE 712,0:POKE 708,64:POKE 709,130:DIM C(21),S(21)
15 FOR I=0 TO 21:C(I)=COS(I*.3):S(I)=SIN(I*.3):NEXT I
20 R=0:F=1
22 TRAP 30:T=NOT T:COLOR T+1
25 FOR B=1 TO F:R=R+1:PLOT 79+R,47:F.I=0 TO 21:DR.R*C(I)+79,-R*S(I)+47
26 T=NOT T:COLOR T+1
27 NEXT I:NEXT B:F=F+1:GOTO 22
30 POKE 708,64:POKE 709,130:GOS.100
35 POKE 709,64:POKE 708,130:GOS.100:GOTO 30
100 FOR B=1 TO 228-PADDLE(1):NEXT B:RET.

This'll draw a dart-board like circle (sorta like a bent checker-board)
made of the best blue/red combo I could come up with for red/blue 3d
glasses.  If you have a red/green, try adjusting the 130 to something
around 194, perhaps (maybe post the best green).
To adjust the speed, use paddle 2.  If you don't have paddles (how dare
you!), just make the "228-PADDLE(1)" some number.  Now put on the glasses
and just stare!  Really hypnotic!  If I used drugs, it might be even
BETTER!...  but I'm not going to start for just a demo.!! ;)

Maybe one of you has had experience with bio-feedback.  Now THAT'd be the
best!  I more mellow you get, the slower the colors cycle!

The next post will have a somewhat shorter program that does a different
demo, but still for 3d glasses.
Just for fun, here's a quick run-down of this one:
line 10-set/screen and color and an array to capture some trig stuff (for
speed)
line 15-capture the trig stuff
line 20-set a couple-a variables (radius and F (why?, who knows!  
probably has some strang meaning in the universe!).. F gets bigger to
make the dartboard effect, rather than just bars of light coming from the
center.
line 22-trap and do the dartboard color set-up (one more color toggle)
line 25-uses B to go F times..makes the Radius bigger, draws a circle
line 26-toggles color
line 27-closes FOR loops and loops circle
lines 30-35-changes colors and gosubs the pause loop
line 100-pauses depending on paddle turn
                        later!  Enjoy this demo!  (probably still looks
good without the 3d glasses, so try it if you're really bored!)

_______________________________________
| PhBill:  Bill Kendrick      Atari   |

| 20 so miles North of         8-bits |
| San Francisco, in beautiful   ROCK! |
|_______Marin!________________________|

2. Discussion web and ASP

3. 3D glasses

4. Benchmarking in Software.

5. 3d Glasses

6. MIDI to MOD conversion

7. 3D glasses.. and the XF551

8. IS LATEST MAC VERSION ALSO SO FULL OF BUGS (like Windows version)?!!!

9. Stereo-tek 3D-glasses

10. Stereo-tek 3d glasses?

11. Stero Tek 3D Glasses 4 sale

12. stereo-tek 3D glasses!!!